Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

Mouse.onMouseDown

Доступность

Flash Player 6.

Синтаксис

someListener.onMouseDown

Параметры

Нет.

Описание

Слушатель событий (Listener); оповещается, когда происходит нажатие левой кнопки мыши. Чтобы использовать листнер onMouseDown, сначала необходимо создать слушающий объект. Затем вы можете создать функцию, вызываемую при оповещении листенера onMouseDown и использовать метод addListener() для регистрации листенера в объекте Mouse, как показано ниже:

var someListener:Object = new Object();
someListener.onMouseDown = function() { ... };
Mouse.addListener(someListener);

Листнеры позволяют различным фрагментам кода работать совместно, потому что оповещение об одном событии могут получить несколько листнеров одновременно.

Пример

В примере ниже используется Drawing API для рисования прямоугольника, когда пользователь нажимает левую кнопку, двигает мышь и отпускает ее.

this.createEmptyMovieClip("canvas_mc", this.getNextHighestDepth());
var mouseListener:Object = new Object();
mouseListener.onMouseDown = function() {
  this.isDrawing = true;
  this.orig_x = _xmouse;
  this.orig_y = _ymouse;
  this.target_mc = canvas_mc.createEmptyMovieClip("", canvas_mc.getNextHighestDepth());
};
mouseListener.onMouseMove = function() {
  if (this.isDrawing) {
    this.target_mc.clear();
    this.target_mc.lineStyle(1, 0xFF0000, 100);
    this.target_mc.moveTo(this.orig_x, this.orig_y);
    this.target_mc.lineTo(_xmouse, this.orig_y);
    this.target_mc.lineTo(_xmouse, _ymouse);
    this.target_mc.lineTo(this.orig_x, _ymouse);
    this.target_mc.lineTo(this.orig_x, this.orig_y);
  }
  updateAfterEvent();
};
mouseListener.onMouseUp = function() {
  this.isDrawing = false;
};
Mouse.addListener(mouseListener);

См. также

Mouse.addListener()

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление